.subckt ecc81 1 2 3
+ params: mu=68.899 ex=1.37499 kg1=598 kp=226.23 kvb=1375 vct=0.4 rgi=2000
+ ccg=2.8p cgp=2.1p ccp=0.7p
e1 7 0 value={v(1,3)/kp*log(1+exp(kp*(1/mu+(v(2,3)+vct)/sqrt(kvb+v(1,3)*v(1,3)))))}
re1 7 0 1G
g1 1 3 value= {(pwr(v(7),ex)+pwrs(v(7),ex))/kg1}
rcp 1 3 1G
c1 2 3 {ccg}
c2 1 2 {cgp}
c3 1 3 {ccp}
r1 2 5 {rgi}
d3 5 3 dx
.model dx d(is=1n rs=1 cjo=10pf tt=1n)
.ends

.subckt ecc82 1 2 3
+ params: mu=19 ex=1.3989 kg1=2031 kp=314.73 kvb=4690 rgi=2000
+ ccg=2.3p cgp=2.4p ccp=1.0p
e1 7 0 value={v(1,3)/kp*log(1+exp(kp*(1/mu+v(2,3)/sqrt(kvb+v(1,3)*v(1,3)))))}
re1 7 0 1G
g1 1 3 value= {(pwr(v(7),ex)+pwrs(v(7),ex))/kg1}
rcp 1 3 1G
c1 2 3 {ccg}
c2 1 2 {cgp}
c3 1 3 {ccp}
r1 2 5 {rgi}
d3 5 3 dx
.model dx d(is=1n rs=1 cjo=10pf tt=1n)
.ends

.subckt ecc83 1 2 3
+ params: mu=100 ex=1.062 kg1=1022 kp=600 kvb=5610 rgi=2000
+ ccg=2.3p cgp=2.4p ccp=.9p
e1 7 0 value={v(1,3)/kp*log(1+exp(kp*(1/mu+v(2,3)/sqrt(kvb+v(1,3)*v(1,3)))))}
re1 7 0 1G
g1 1 3 value= {(pwr(v(7),ex)+pwrs(v(7),ex))/kg1}
rcp 1 3 1G
c1 2 3 {ccg}
c2 1 2 {cgp}
c3 1 3 {ccp}
r1 2 5 {rgi}
d3 5 3 dx
.model dx d(is=1n rs=1 cjo=10pf tt=1n)
.ends

.subckt ECC84 1 2 3
+ params: mu=32.6 ex=1.8597 kg1=1088 kp=63.5 kvb=1415 vct=1.2 rgi=2000
+ ccg=2.6p cgp=1.7p ccp=0.95p
e1 7 0 value={v(1,3)/kp*log(1+exp(kp*(1/mu+(v(2,3)+vct)/sqrt(kvb+v(1,3)*v(1,3)))))}
re1 7 0 1G
g1 1 3 value= {(pwr(v(7),ex)+pwrs(v(7),ex))/kg1}
rcp 1 3 1G
c1 2 3 {ccg}
c2 1 2 {cgp}
c3 1 3 {ccp}
r1 2 5 {rgi}
d3 5 3 dx
.model dx d(is=1n rs=1 cjo=10pf tt=1n)
.ends

.subckt ECC85 1 2 3
+ params: mu=73.099 ex=1.7519 kg1=655 kp=163.5 kvb=140 vct=0.739 rgi=2000
+ ccg=3.6p cgp=2.0p ccp=0.67p
e1 7 0 value={v(1,3)/kp*log(1+exp(kp*(1/mu+(v(2,3)+vct)/sqrt(kvb+v(1,3)*v(1,3)))))}
re1 7 0 1G
g1 1 3 value= {(pwr(v(7),ex)+pwrs(v(7),ex))/kg1}
rcp 1 3 1G
c1 2 3 {ccg}
c2 1 2 {cgp}
c3 1 3 {ccp}
r1 2 5 {rgi}
d3 5 3 dx
.model dx d(is=1n rs=1 cjo=10pf tt=1n)
.ends

.subckt ecc99  1 2 3
+ PARAMS: MU=22 EX=1.5549 KG1=570 KP=300 KVB=395  RGI=2000
+ CCG=6.3P CGP=5.6P CCP=1.41P
E1 7 0 VALUE={V(1,3)/KP*LOG(1+EXP(KP*(1/MU+V(2,3)/SQRT(KVB+V(1,3)*V(1,3)))))} 
RE1 7 0 1G 
G1 1 3 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1} 
RCP 1 3 1G ; TO AVOID FLOATING NODES IN MU-FOLLOWER 
C1 2 3 {CCG} ; CATHODE-GRID 
C2 2 1 {CGP} ; GRID=PLATE 
C3 1 3 {CCP} ; CATHODE-PLATE 
D3 5 3 DX ; FOR GRID CURRENT 
R1 2 5 {RGI} ; FOR GRID CURRENT 
.model DX D(IS=1N RS=1 CJO=10PF TT=1N) 
.ends

.SUBCKT EL34 1 2 3 4 ; A G2 G1 K (PENTODE)
+ PARAMS: MU=11.8889 EX=1.2786 KG1=525.5 KG2=1200 KP=55.5097 KVB=11.9 vct=-1.46
+ CCG=16P CPG1=1.8P CCP=10.5P RGI=1K
RE1 7 0 1MEG
E1 7 0 VALUE={V(2,4)/KP*LOG(1+EXP(KP*(1/MU+(V(3,4)+vct)/V(2,4))))}
G1 1 4 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}
G2 2 4 VALUE={(exp(EX*(log((V(2,4)/MU)+v(3,4)))))/KG2}
RCP 1 4 1G ; FOR CONVERGENCE
C1 3 4 {CCG} ; CATHODE-GRID 1
C2 1 3 {CPG1} ; GRID 1-PLATE
C3 1 4 {CCP} ; CATHODE-PLATE
R1 3 5 {RGI} ; FOR GRID CURRENT
D3 5 4 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS 

.SUBCKT EL84 1 2 3 4 ; A G2 G1 K (PENTODE)
+ PARAMS: MU=20.5886 EX=1.3669 KG1=525.5 KG2=1570 KP=115.5094 KVB=42.899 vct=0.0
+ CCG=10.5P CPG1=1.1P CCP=5.6P RGI=20K
RE1 7 0 1MEG
E1 7 0 VALUE={V(2,4)/KP*LOG(1+EXP(KP*(1/MU+(V(3,4)+vct)/V(2,4))))}
G1 1 4 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}
G2 2 4 VALUE={(exp(EX*(log((V(2,4)/MU)+v(3,4)))))/KG2}
RCP 1 4 1G ; FOR CONVERGENCE
C1 3 4 {CCG} ; CATHODE-GRID 1
C2 1 3 {CPG1} ; GRID 1-PLATE
C3 1 4 {CCP} ; CATHODE-PLATE
R1 3 5 {RGI} ; FOR GRID CURRENT
D3 5 4 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS 

.SUBCKT ECL86 1 2 3 4 ; A G2 G1 K (PENTODE)
+ PARAMS: MU=24.1886 EX=1.3669 KG1=525.5 KG2=1050 KP=109.5093 KVB=19.899 vct=0.0
+ CCG=10.5P CPG1=0.9P CCP=10P RGI=1K
RE1 7 0 1MEG
E1 7 0 VALUE={V(2,4)/KP*LOG(1+EXP(KP*(1/MU+(V(3,4)+vct)/V(2,4))))}
G1 1 4 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}
G2 2 4 VALUE={(exp(EX*(log((V(2,4)/MU)+v(3,4)))))/KG2}
RCP 1 4 1G ; FOR CONVERGENCE
C1 3 4 {CCG} ; CATHODE-GRID 1
C2 1 3 {CPG1} ; GRID 1-PLATE
C3 1 4 {CCP} ; CATHODE-PLATE
R1 3 5 {RGI} ; FOR GRID CURRENT
D3 5 4 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS 

.SUBCKT EF86 1 2 3 4 ; A G2 G1 K (PENTODE)
+ PARAMS: MU=50.598 EX=1.24589 KG1=672.5 KG2=1050 KP=166.308 KVB=313.899 vct=0.4699
+ CCG=4.3P CPG1=0.1P CCP=5.8P RGI=2K
RE1 7 0 1MEG
E1 7 0 VALUE={V(2,4)/KP*LOG(1+EXP(KP*(1/MU+(V(3,4)+vct)/V(2,4))))}
G1 1 4 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}
G2 2 4 VALUE={(exp(EX*(log((V(2,4)/MU)+v(3,4)))))/KG2}
RCP 1 4 1G ; FOR CONVERGENCE
C1 3 4 {CCG} ; CATHODE-GRID 1
C2 1 3 {CPG1} ; GRID 1-PLATE
C3 1 4 {CCP} ; CATHODE-PLATE
R1 3 5 {RGI} ; FOR GRID CURRENT
D3 5 4 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

.SUBCKT EF95 1 2 3 4 ; A G2 G1 K (PENTODE)
+ PARAMS: MU=30.798 EX=1.2857 KG1=535.5 KG2=1200 KP=104.497 KVB=105.89901 vct=-0.519
+ CCG=4.5P CPG1=0.53P CCP=2.6P RGI=2K
RE1 7 0 1MEG
E1 7 0 VALUE={V(2,4)/KP*LOG(1+EXP(KP*(1/MU+(V(3,4)+vct)/V(2,4))))}
G1 1 4 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}
G2 2 4 VALUE={(exp(EX*(log((V(2,4)/MU+0.5)+v(3,4)))))/KG2}
RCP 1 4 1G ; FOR CONVERGENCE
C1 3 4 {CCG} ; CATHODE-GRID 1
C2 1 3 {CPG1} ; GRID 1-PLATE
C3 1 4 {CCP} ; CATHODE-PLATE
R1 3 5 {RGI} ; FOR GRID CURRENT
D3 5 4 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS

.SUBCKT 6V6GT 1 2 3 4 ; A G2 G1 K (PENTODE)
+ PARAMS: MU=9.9887 EX=1.1604 KG1=1108.5 KG2=4700 KP=48.7094 KVB=6.899 vct=-1.9
+ CCG=9.5P CPG1=1.2P CCP=8P RGI=1K
RE1 7 0 1MEG
E1 7 0 VALUE={V(2,4)/KP*LOG(1+EXP(KP*(1/MU+(V(3,4)+vct)/V(2,4))))}
G1 1 4 VALUE={(PWR(V(7),EX)+PWRS(V(7),EX))/KG1*ATAN(V(1,4)/KVB)}
G2 2 4 VALUE={(exp(EX*(log((V(2,4)/MU)+v(3,4)))))/KG2}
RCP 1 4 1G ; FOR CONVERGENCE
C1 3 4 {CCG} ; CATHODE-GRID 1
C2 1 3 {CPG1} ; GRID 1-PLATE
C3 1 4 {CCP} ; CATHODE-PLATE
R1 3 5 {RGI} ; FOR GRID CURRENT
D3 5 4 DX ; FOR GRID CURRENT
.MODEL DX D(IS=1N RS=1 CJO=10PF TT=1N)
.ENDS 

.SUBCKT TRIODE A G K H1 H2
+PARAMS: RCO=1.6 RHO=10.5 HTV=6.3 HWU=10.5
+ LIP=1 LIF=3.7E-3 RAF=18E-3 RAS=1 CDO=0 RAP=4E-3
+ ERP=1.5 
+ MU0=17.3 MUR=19E-3 EMC=9.6E-6 GCO=0 GCF=213E-6
+ CGA=3.9p CGK=2.4p CAK=0.7p 
Rcool H1 HA {RCO}
Rload HA HB 1M
Esens HD 0  VALUE {V(HA,HB)*1000}
Epwr  HE 0  VALUE {V(H1,H2)*V(HD)/(PWR({HTV},2)/{RHO})}
RH1   HE HF 91k
CH1   HF 0  {HWU/1E6}
EH2   HG 0  VALUE {V(HF)}
RH2   HG HH 270k
CH2   HH 0  {HWU/1E6}
EH3   HJ 0  VALUE {LIMIT(V(HH)-0.75,0,1E6)*4}
RH3   HJ HK 91k
CH3   HK 0  {HWU/1E6}
Ghot  HB H2 VALUE {(1/(V(HG)+0.001))/({RHO}-{RCO})*V(HB,H2)}
Elim  LI 0  VALUE {PWR(LIMIT(V(A,K),0,1E6),{LIP})*{LIF}}
Egg   GG 0  VALUE {V(G,K)-{CDO}}
Erpf  RP 0  VALUE {1-PWR(LIMIT(-V(GG)*{RAF},0,0.999),{RAS})+LIMIT(V(GG),0,1E6)*{RAP}}
Egr   GR 0  VALUE {LIMIT(V(GG),0,1E6)+LIMIT((V(GG))*(1+V(GG)*{MUR}),0,-1E6)}
Eem   EM 0  VALUE {LIMIT(V(A,K)+V(GR)*{MU0},0,1E6)}
Eep   EP 0  VALUE {PWR(V(EM),ERP)*{EMC}*V(RP)}
Eel   EL 0  VALUE {LIMIT(V(EP),0,V(LI))}
Eld   LD 0  VALUE {LIMIT(V(EP)-V(LI),0,1E6)}
Ga    A  K  VALUE {V(HK)*V(EL)}
Egf   GF 0  VALUE {PWR(LIMIT(V(G,K)-{GCO},0,1E6),1.5)*{GCF}}
Gg    G  K  VALUE {(V(GF)+V(LD))*V(HK)}
CM1	G	K	{CGK}
CM2	A	G	{CGA}
CM3	A	K	{CAK}
RF1	A	0	1000MEG
RF2	G	0	1000MEG
RF3	K	0	1000MEG
.ENDS

.SUBCKT TRIODENH A G K
+PARAMS: LIP=1 LIF=3.7E-3 RAF=18E-3 RAS=1 CDO=0 RAP=4E-3
+ ERP=1.5
+ MU0=17.3 MUR=19E-3 EMC=9.6E-6 GCO=0 GCF=213E-6
+ CGA=3.9p CGK=2.4p CAK=0.7p 
Elim  LI 0  VALUE {PWR(LIMIT(V(A,K),0,1E6),{LIP})*{LIF}}
Egg   GG 0  VALUE {V(G,K)-{CDO}}
Erpf  RP 0  VALUE {1-PWR(LIMIT(-V(GG)*{RAF},0,0.999),{RAS})+LIMIT(V(GG),0,1E6)*{RAP}}
Egr   GR 0  VALUE {LIMIT(V(GG),0,1E6)+LIMIT((V(GG))*(1+V(GG)*{MUR}),0,-1E6)}
Eem   EM 0  VALUE {LIMIT(V(A,K)+V(GR)*{MU0},0,1E6)}
Eep   EP 0  VALUE {PWR(V(EM),ERP)*{EMC}*V(RP)}
Eel   EL 0  VALUE {LIMIT(V(EP),0,V(LI))}
Eld   LD 0  VALUE {LIMIT(V(EP)-V(LI),0,1E6)}
Ga    A  K  VALUE {V(EL)}
Egf   GF 0  VALUE {PWR(LIMIT(V(G,K)-{GCO},0,1E6),1.5)*{GCF}}
Gg    G  K  VALUE {(V(GF)+V(LD))}
CM1	G	K	{CGK}
CM2	A	G	{CGA}
CM3	A	K	{CAK}
RF1	A	0	1000MEG
RF2	G	0	1000MEG
RF3	K	0	1000MEG
.ENDS

.SUBCKT ECC88 A G K
XV1 A G K TRIODENH
+PARAMS: LIP= 1.5 LIF= 10 RAF= 0.09 RAS= 0.2 CDO= 0 
+ RAP= 0 ERP= 1.35 
+ MU0= 33 MUR= 0.02 EMC= 0.0000795 
+ GCO=-0.2 GCF= 0 
+ CGA=1.40E-12 CGK=3.30E-12 CAK=1.80E-12
.ENDS

.SUBCKT  6L6GC P S G K
Esp 2  0  VALUE={V(P,K)+15.15*V(S,K)+134.6*V(G,K)}
E1  3  2  VALUE={7.731E-7*(PWR(V(2),1.5)+PWRS(V(2),1.5))/2}
E2  3  4  VALUE={7.731E-7*PWR(15.15*V(S,K),1.5)*V(P,K)/60}
E3  5  4  VALUE={(1-V(4,2)/ABS(V(4,2)+0.001))/2}
R1  5  0  1.0K
Gk  S  K  VALUE={V(3,2)}
Gp  P  S  VALUE={0.94*(V(3,4)*(1-V(5,4))+V(3,2)*V(5,4))}
Cgk G  K  5P
Cgs G  S  5P
Cgp G  P  0.6P
Cpk P  K  6.5P
.ENDS 6L6GC